Script to rename files in a folder.

Dim sInputFolder
Dim oFs: Set oFs = CreateObject("Scripting.FileSystemObject")
	Main()
Set oFs = Nothing

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub Main()
	GetArguments()

	RenameFiles(sInputFolder)
End Sub

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub GetArguments()

Dim oArgs: Set oArgs = WScript.Arguments

	If oArgs.Count <> 1 Then
		WScript.Echo(INVALID_ARG_ERR)
		WScript.Quit(INVALID_ARG_RET)
	End If

	sInputFolder = oArgs(0)

	Set oArgs = Nothing

End Sub

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub RenameFiles(ByVal psFolderPath)

Dim iCnt
Dim oFolder
Dim oFile
	If oFs.FolderExists(psFolderPath) Then
		Set oFolder = oFs.GetFolder(psFolderPath)
		For Each oFile In oFolder.Files
			'### *** ### CHANGE THIS CODE TO CHECK FOR FILES THAT NEED TO BE RENAMED
			If InStr(1, oFile.Name, ".jpg_Resized") > 0 Then
				RenameFile(oFile.Path)
			End If
		Next
	Else
		WScript.Echo(Replace(FOLDER_MISSING_ERR, "$FolderName", psFolderPath))
		WScript.Quit(FOLDER_MISSING_RET)
	End If

End Sub

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub RenameFile(ByVal psFileName)

Dim aTemp
Dim sFilePath, _
	sFileName, _
	sFileName_Target

	aTemp = Split(psFileName, "\")
	sFileName = aTemp(UBound(aTemp))

	'### *** ### CHANGE THIS CODE TO END UP WITH THE TARGET FILENAME THAT YOU WANT
	sFileName_Target = Replace(sFileName, ".jpg_Resized.jpg", "_Resized.jpg")
	
	sFilePath = Left(psFileName, Len(psFileName) - Len(sFileName))

	On Error Resume Next
	If oFs.FileExists(psFileName) Then
		If oFs.FileExists(sFilePath & sFileName_Target) Then
			oFs.DeleteFile(sFilePath & sFileName_Target)
		End If
		
		oFs.MoveFile psFileName, sFilePath & sFileName_Target
	Else
		WScript.Echo(Replace(FILE_MISSING_ERR, "$FileName", psFileName))
		WScript.Quit(FILE_MISSING_RET)
	End If
	On Error Goto 0

End Sub

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Const INVALID_ARG_RET = 1
Const INVALID_ARG_ERR = "You must provide a path of the files you wish to rename."

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Const FILE_MISSING_RET = 51
Const FILE_MISSING_ERR = "File Does Not Exist: $FileName"

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Const FOLDER_MISSING_RET = 2
Const FOLDER_MISSING_ERR = "Folder Does Not Exist: $FolderPath"

C:\fileRenamer.vbs "C:\Path\To\Files\That\Need\Renamed\"